Sub Download\_Notes\_Emails()

''\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*''

' Download Aims email content from Lotus Notes '

''\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*''

''DECLARE VARIABLES FOR MACRO WORKBOOK AND WORKSHEET

Dim mwb As Workbook

Set mwb = ThisWorkbook

Dim mws1 As Worksheet, mws2 As Worksheet

Set mws1 = mwb.Sheets("Report")

Set mws2 = mwb.Sheets("Emails")

Dim stPath As String

stPath = ThisWorkbook.Path & "\"

Dim Lastrow\_Emails As Integer

Lastrow\_Emails = mws2.Cells(Rows.Count, 1).End(xlUp).row 'Stores last row of 'Emails' Sheet

''CLEAN UP PAST CONTENT

mws2.Range("A1:A" & Lastrow\_Emails).ClearContents

''DECLARE VARIABLES FOR LOTUS NOTES

Dim noSession As Object 'Notes Session

Dim noDatabase As Object 'Notes Database

Dim noView As Object 'Notes View

Dim noDocument As Object 'Notes Document

Dim noNextDocument As Object 'Next Notes Document

Dim noItem As Object 'Notes Item

Dim mailServer As String

Dim mailFile As String

Dim lines As Variant

''INSTATNTIATE THE NOTES SESSION

Set noSession = CreateObject("Notes.NotesSession")

''INSTANTIATE THE ACTUAL NOTES DATABASE

mailServer = noSession.GetEnvironmentString("MailServer", True)

mailFile = noSession.GetEnvironmentString("MailFile", True)

Set noDatabase = noSession.GetDatabase(mailServer, mailFile) 'User's default server and database

''SET NOTES VIEW TO FIXING TO STORE ALL AIMS EMAIL

Set noView = noDatabase.GetView("Fixing")

noView.AutoUpdate = False

''SET FIRST EMAIL IN FIXING VIEW

Set noDocument = noView.GetFirstDocument

''ITERATE THROUGH ALL THE EMAILS IN FIXING VIEW

Do Until noDocument Is Nothing

Set noNextDocument = noView.GetNextDocument(noDocument)

Set noItem = noDocument.GetFirstItem("Body")

If Not noItem Is Nothing Then

lines = Split(noItem.Text, vbCrLf)

Lastrow\_Emails = mws2.Cells(Rows.Count, 1).End(xlUp).row 'Refreshes last row of 'Emails' sheet

mws2.Cells(Lastrow\_Emails + 1, 1).Resize(UBound(lines) + 1, 1).Value = Application.WorksheetFunction.Transpose(lines)

End If

Set noDocument = noNextDocument

Loop

''RELEASE OBJECTS FROM MEMORY

Set noNextDocument = Nothing

Set noDocument = Nothing

Set noView = Nothing

Set noDatabase = Nothing

Set noSession = Nothing

Set noItem = Nothing

End Sub

Option Explicit

Public NextTick As Date

Sub ScheduleOn()

NextTick = Now + TimeValue("00:05:00")

Application.OnTime NextTick, "Save\_Attachments"

End Sub

Sub Save\_Attachments()

''\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*''

' Download all email attachments from EBS '

''\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*''

''Declare all necessary variables

Dim wb As Workbook

Set wb = ThisWorkbook

Dim stPath As String

stPath = ThisWorkbook.Path & "\"

Dim noSession As Object

Dim noDatabase As Object

Dim noView As Object

Dim noDocument As Object

Dim noNextDocument As Object

Dim mailServer As String

Dim mailFile As String

Const EMBED\_ATTACHMENT As Long = 1454

Const RICHTEXT As Long = 1

''Embedded objects are of the datatype Variant.

Dim vaItem As Variant

'Dim temp As Variant 'Stores the file name temporarily for matching purposes

Dim vaAttachment As Variant

''Instantiate the Notes session.

Set noSession = CreateObject("Notes.NotesSession")

''Instantiate the actual Notes database.

mailServer = noSession.GetEnvironmentString("MailServer", True)

mailFile = noSession.GetEnvironmentString("MailFile", True)

Set noDatabase = noSession.GetDatabase(mailServer, mailFile)

''Folders are views in Lotus Notes and in this example the EBS folder is used to store all the NDF reports.

Set noView = noDatabase.GetView("EBS")

noView.AutoUpdate = False

''Get the first document in the defined view.

Set noDocument = noView.GetFirstDocument

''Iterate through all the e-mails in the EBS folder.

Dim k As Integer 'Create a unique identifier for attachments with same filename

k = 0 'Initialise k

Do Until noDocument Is Nothing

Set noNextDocument = noView.GetNextDocument(noDocument)

''Check if the document has an attachment or not.

If noDocument.HasEmbedded Then

Set vaItem = noDocument.GetFirstItem("Body")

If vaItem.Type = RICHTEXT Then

For Each vaAttachment In vaItem.EmbeddedObjects

If vaAttachment.Type = EMBED\_ATTACHMENT Then

''Match the current file name against preceding file name

' If vaAttachment.Name <> temp Then

''Save attachments into the designated folder

vaAttachment.ExtractFile stPath & vaAttachment.Name

' k = k + 1

' ''Rename files with same filenames and save them into the designated folder

' ElseIf vaAttachment.Name = temp Then

' vaAttachment.ExtractFile stPath & Replace(vaAttachment.Name, ".", k & ".")

' k = k + 1

' End If

' ''Update the file name in temp for subsequent matching purposes

' temp = vaAttachment.Name

End If

Next vaAttachment

End If

End If

Set noDocument = noNextDocument

Loop

''Release objects from memory.

Set noNextDocument = Nothing

Set noDocument = Nothing

Set noView = Nothing

Set noDatabase = Nothing

Set noSession = Nothing

Set vaItem = Nothing

Call ScheduleOn

'MsgBox "All the attachments in the EBS folder have successfully been saved."

End Sub

Sub ScheduleOff()

Application.OnTime EarliestTime:=NextTick, Procedure:="Save\_Attachments", Schedule:=False

End Sub